[Summary view] [Print] [Text view]

   1  =head1 NAME
   2  
   3  perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4  
   5  =head1 DESCRIPTION
   6  
   7  The top level documentation about Perl regular expressions
   8  is found in L<perlre>.
   9  
  10  This document describes all backslash and escape sequences. After
  11  explaining the role of the backslash, it lists all the sequences that have
  12  a special meaning in Perl regular expressions (in alphabetical order),
  13  then describes each of them.
  14  
  15  Most sequences are described in detail in different documents; the primary
  16  purpose of this document is to have a quick reference guide describing all
  17  backslash and escape sequences.
  18  
  19  
  20  =head2 The backslash
  21  
  22  In a regular expression, the backslash can perform one of two tasks:
  23  it either takes away the special meaning of the character following it
  24  (for instance, C<\|> matches a vertical bar, it's not an alternation),
  25  or it is the start of a backslash or escape sequence.
  26  
  27  The rules determining what it is are quite simple: if the character
  28  following the backslash is a punctuation (non-word) character (that is,
  29  anything that is not a letter, digit or underscore), then the backslash
  30  just takes away the special meaning (if any) of the character following
  31  it.
  32  
  33  If the character following the backslash is a letter or a digit, then the
  34  sequence may be special; if so, it's listed below. A few letters have not
  35  been used yet, and escaping them with a backslash is safe for now, but a
  36  future version of Perl may assign a special meaning to it. However, if you
  37  have warnings turned on, Perl will issue a warning if you use such a sequence.
  38  [1].
  39  
  40  It is however guaranteed that backslash or escape sequences never have a
  41  punctuation character following the backslash, not now, and not in a future
  42  version of Perl 5. So it is safe to put a backslash in front of a non-word
  43  character.
  44  
  45  Note that the backslash itself is special; if you want to match a backslash,
  46  you have to escape the backslash with a backslash: C</\\/> matches a single
  47  backslash.
  48  
  49  =over 4
  50  
  51  =item [1]
  52  
  53  There is one exception. If you use an alphanumerical character as the
  54  delimiter of your pattern (which you probably shouldn't do for readability
  55  reasons), you will have to escape the delimiter if you want to match
  56  it. Perl won't warn then. See also L<perlop/Gory details of parsing
  57  quoted constructs>.
  58  
  59  =back
  60  
  61  
  62  =head2 All the sequences and escapes
  63  
  64   \000              Octal escape sequence.
  65   \1                Absolute backreference.
  66   \a                Alarm or bell.
  67   \A                Beginning of string.
  68   \b                Word/non-word boundary. (Backspace in a char class).
  69   \B                Not a word/non-word boundary.
  70   \cX               Control-X (X can be any ASCII character).
  71   \C                Single octet, even under UTF-8.
  72   \d                Character class for digits.
  73   \D                Character class for non-digits.
  74   \e                Escape character.
  75   \E                Turn off \Q, \L and \U processing.
  76   \f                Form feed.
  77   \g{}, \g1         Named, absolute or relative backreference.
  78   \G                Pos assertion.
  79   \h                Character class for horizontal white space.
  80   \H                Character class for non horizontal white space.
  81   \k{}, \k<>, \k''  Named backreference.
  82   \K                Keep the stuff left of \K.
  83   \l                Lowercase next character.
  84   \L                Lowercase till \E.
  85   \n                (Logical) newline character.
  86   \N{}              Named (Unicode) character.
  87   \p{}, \pP         Character with a Unicode property.
  88   \P{}, \PP         Character without a Unicode property.
  89   \Q                Quotemeta till \E.
  90   \r                Return character.
  91   \R                Generic new line.
  92   \s                Character class for white space.
  93   \S                Character class for non white space.
  94   \t                Tab character.
  95   \u                Titlecase next character.
  96   \U                Uppercase till \E.
  97   \v                Character class for vertical white space.
  98   \V                Character class for non vertical white space.
  99   \w                Character class for word characters.
 100   \W                Character class for non-word characters.
 101   \x{}, \x00        Hexadecimal escape sequence.
 102   \X                Extended Unicode "combining character sequence".
 103   \z                End of string.
 104   \Z                End of string.
 105  
 106  =head2 Character Escapes
 107  
 108  =head3  Fixed characters
 109  
 110  A handful of characters have a dedicated I<character escape>. The following
 111  table shows them, along with their code points (in decimal and hex), their
 112  ASCII name, the control escape (see below) and a short description.
 113  
 114   Seq.  Code Point  ASCII   Cntr    Description.
 115         Dec    Hex
 116    \a     7     07    BEL    \cG    alarm or bell
 117    \b     8     08     BS    \cH    backspace [1]
 118    \e    27     1B    ESC    \c[    escape character
 119    \f    12     0C     FF    \cL    form feed
 120    \n    10     0A     LF    \cJ    line feed [2]
 121    \r    13     0D     CR    \cM    carriage return
 122    \t     9     09    TAB    \cI    tab
 123  
 124  =over 4
 125  
 126  =item [1]
 127  
 128  C<\b> is only the backspace character inside a character class. Outside a
 129  character class, C<\b> is a word/non-word boundary.
 130  
 131  =item [2]
 132  
 133  C<\n> matches a logical newline. Perl will convert between C<\n> and your
 134  OSses native newline character when reading from or writing to text files.
 135  
 136  =back
 137  
 138  =head4 Example
 139  
 140   $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 141  
 142  =head3 Control characters
 143  
 144  C<\c> is used to denote a control character; the character following C<\c>
 145  is the name of the control character. For instance, C</\cM/> matches the
 146  character I<control-M> (a carriage return, code point 13). The case of the
 147  character following C<\c> doesn't matter: C<\cM> and C<\cm> match the same
 148  character.
 149  
 150  Mnemonic: I<c>ontrol character.
 151  
 152  =head4 Example
 153  
 154   $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 155  
 156  =head3 Named characters
 157  
 158  All Unicode characters have a Unicode name, and characters in various scripts
 159  have names as well. It is even possible to give your own names to characters.
 160  You can use a character by name by using the C<\N{}> construct; the name of
 161  the character goes between the curly braces. You do have to C<use charnames>
 162  to load the names of the characters, otherwise Perl will complain you use
 163  a name it doesn't know about. For more details, see L<charnames>.
 164  
 165  Mnemonic: I<N>amed character.
 166  
 167  =head4 Example
 168  
 169   use charnames ':full';               # Loads the Unicode names.
 170   $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 171  
 172   use charnames 'Cyrillic';            # Loads Cyrillic names.
 173   $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 174  
 175  =head3 Octal escapes
 176  
 177  Octal escapes consist of a backslash followed by two or three octal digits
 178  matching the code point of the character you want to use. This allows for
 179  512 characters (C<\00> up to C<\777>) that can be expressed this way.
 180  Enough in pre-Unicode days, but most Unicode characters cannot be escaped
 181  this way.
 182  
 183  Note that a character that is expressed as an octal escape is considered
 184  as a character without special meaning by the regex engine, and will match
 185  "as is".
 186  
 187  =head4 Examples
 188  
 189   $str = "Perl";
 190   $str =~ /\120/;    # Match, "\120" is "P".
 191   $str =~ /\120+/;   # Match, "\120" is "P", it is repeated at least once.
 192   $str =~ /P\053/;   # No match, "\053" is "+" and taken literally.
 193  
 194  =head4 Caveat
 195  
 196  Octal escapes potentially clash with backreferences. They both consist
 197  of a backslash followed by numbers. So Perl has to use heuristics to
 198  determine whether it is a backreference or an octal escape. Perl uses
 199  the following rules:
 200  
 201  =over 4
 202  
 203  =item 1
 204  
 205  If the backslash is followed by a single digit, it's a backreference.
 206  
 207  =item 2
 208  
 209  If the first digit following the backslash is a 0, it's an octal escape.
 210  
 211  =item 3
 212  
 213  If the number following the backslash is N (decimal), and Perl already has
 214  seen N capture groups, Perl will consider this to be a backreference.
 215  Otherwise, it will consider it to be an octal escape. Note that if N > 999,
 216  Perl only takes the first three digits for the octal escape; the rest is
 217  matched as is.
 218  
 219   my $pat  = "(" x 999;
 220      $pat .= "a";
 221      $pat .= ")" x 999;
 222   /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 223   /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 224                      #    and \1000 is seen as \100 (a '@') and a '0'.
 225  
 226  =back
 227  
 228  =head3 Hexadecimal escapes
 229  
 230  Hexadecimal escapes start with C<\x> and are then either followed by
 231  two digit hexadecimal number, or a hexadecimal number of arbitrary length
 232  surrounded by curly braces. The hexadecimal number is the code point of
 233  the character you want to express.
 234  
 235  Note that a character that is expressed as a hexadecimal escape is considered
 236  as a character without special meaning by the regex engine, and will match
 237  "as is".
 238  
 239  Mnemonic: heI<x>adecimal.
 240  
 241  =head4 Examples
 242  
 243   $str = "Perl";
 244   $str =~ /\x50/;    # Match, "\x50" is "P".
 245   $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once.
 246   $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 247  
 248   /\x{2603}\x{2602}/ # Snowman with an umbrella.
 249                      # The Unicode character 2603 is a snowman,
 250                      # the Unicode character 2602 is an umbrella.
 251   /\x{263B}/         # Black smiling face.
 252   /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 253  
 254  =head2 Modifiers
 255  
 256  A number of backslash sequences have to do with changing the character,
 257  or characters following them. C<\l> will lowercase the character following
 258  it, while C<\u> will uppercase (or, more accurately, titlecase) the
 259  character following it. (They perform similar functionality as the
 260  functions C<lcfirst> and C<ucfirst>).
 261  
 262  To uppercase or lowercase several characters, one might want to use
 263  C<\L> or C<\U>, which will lowercase/uppercase all characters following
 264  them, until either the end of the pattern, or the next occurrence of
 265  C<\E>, whatever comes first. They perform similar functionality as the
 266  functions C<lc> and C<uc> do.
 267  
 268  C<\Q> is used to escape all characters following, up to the next C<\E>
 269  or the end of the pattern. C<\Q> adds a backslash to any character that
 270  isn't a letter, digit or underscore. This will ensure that any character
 271  between C<\Q> and C<\E> is matched literally, and will not be interpreted
 272  by the regexp engine.
 273  
 274  Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
 275  
 276  =head4 Examples
 277  
 278   $sid     = "sid";
 279   $greg    = "GrEg";
 280   $miranda = "(Miranda)";
 281   $str     =~ /\u$sid/;        # Matches 'Sid'
 282   $str     =~ /\L$greg/;       # Matches 'greg'
 283   $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 284                                #   had been written as /\(Miranda\)/
 285  
 286  =head2 Character classes
 287  
 288  Perl regular expressions have a large range of character classes. Some of
 289  the character classes are written as a backslash sequence. We will briefly
 290  discuss those here; full details of character classes can be found in
 291  L<perlrecharclass>.
 292  
 293  C<\w> is a character class that matches any I<word> character (letters,
 294  digits, underscore). C<\d> is a character class that matches any digit,
 295  while the character class C<\s> matches any white space character.
 296  New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 297  and vertical white space characters.
 298  
 299  The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 300  character classes that match any character that isn't a word character,
 301  digit, white space, horizontal white space or vertical white space.
 302  
 303  Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 304  
 305  =head3 Unicode classes
 306  
 307  C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 308  match a character that matches the given Unicode property; properties
 309  include things like "letter", or "thai character". Capitalizing the
 310  sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 311  that doesn't match the given Unicode property. For more details, see
 312  L<perlrecharclass/Backslashed sequences> and
 313  L<perlunicode/Unicode Character Properties>.
 314  
 315  Mnemonic: I<p>roperty.
 316  
 317  
 318  =head2 Referencing
 319  
 320  If capturing parenthesis are used in a regular expression, we can refer
 321  to the part of the source string that was matched, and match exactly the
 322  same thing. There are three ways of referring to such I<backreference>:
 323  absolutely, relatively, and by name.
 324  
 325  =for later add link to perlrecapture
 326  
 327  =head3 Absolute referencing
 328  
 329  A backslash sequence that starts with a backslash and is followed by a
 330  number is an absolute reference (but be aware of the caveat mentioned above).
 331  If the number is I<N>, it refers to the Nth set of parenthesis - whatever
 332  has been matched by that set of parenthesis has to be matched by the C<\N>
 333  as well.
 334  
 335  =head4 Examples
 336  
 337   /(\w+) \1/;    # Finds a duplicated word, (e.g. "cat cat").
 338   /(.)(.)\2\1/;  # Match a four letter palindrome (e.g. "ABBA").
 339  
 340  
 341  =head3 Relative referencing
 342  
 343  New in perl 5.10.0 is a different way of referring to capture buffers: C<\g>.
 344  C<\g> takes a number as argument, with the number in curly braces (the
 345  braces are optional). If the number (N) does not have a sign, it's a reference
 346  to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
 347  C<\g> always refers to a capture group and will never be seen as an octal
 348  escape). If the number is negative, the reference is relative, referring to
 349  the Nth group before the C<\g{-N}>.
 350  
 351  The big advantage of C<\g{-N}> is that it makes it much easier to write
 352  patterns with references that can be interpolated in larger patterns,
 353  even if the larger pattern also contains capture groups.
 354  
 355  Mnemonic: I<g>roup.
 356  
 357  =head4 Examples
 358  
 359   /(A)        # Buffer 1
 360    (          # Buffer 2
 361      (B)      # Buffer 3
 362      \g{-1}   # Refers to buffer 3 (B)
 363      \g{-3}   # Refers to buffer 1 (A)
 364    )
 365   /x;         # Matches "ABBA".
 366  
 367   my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 368   /$qr$qr/                           # Matches 'ababcdcd'.
 369  
 370  =head3 Named referencing
 371  
 372  Also new in perl 5.10.0 is the use of named capture buffers, which can be
 373  referred to by name. This is done with C<\g{name}>, which is a
 374  backreference to the capture buffer with the name I<name>.
 375  
 376  To be compatible with .Net regular expressions, C<\g{name}> may also be
 377  written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 378  
 379  Note that C<\g{}> has the potential to be ambiguous, as it could be a named
 380  reference, or an absolute or relative reference (if its argument is numeric).
 381  However, names are not allowed to start with digits, nor are allowed to
 382  contain a hyphen, so there is no ambiguity.
 383  
 384  =head4 Examples
 385  
 386   /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 387   /(?<word>\w+) \k{word}/ # Same.
 388   /(?<word>\w+) \k<word>/ # Same.
 389   /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 390                           # Match a four letter palindrome (e.g. "ABBA")
 391  
 392  =head2 Assertions
 393  
 394  Assertions are conditions that have to be true -- they don't actually
 395  match parts of the substring. There are six assertions that are written as
 396  backslash sequences.
 397  
 398  =over 4
 399  
 400  =item \A
 401  
 402  C<\A> only matches at the beginning of the string. If the C</m> modifier
 403  isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
 404  modifier is used, then C</^/> matches internal newlines, but the meaning
 405  of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 406  of the string regardless whether the C</m> modifier is used.
 407  
 408  =item \z, \Z
 409  
 410  C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 411  used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
 412  end of the string, or before the newline at the end of the string. If the
 413  C</m> modifier is used, then C</$/> matches at internal newlines, but the
 414  meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 415  the end of the string (or just before a trailing newline) regardless whether
 416  the C</m> modifier is used.
 417  
 418  C<\z> is just like C<\Z>, except that it will not match before a trailing
 419  newline. C<\z> will only match at the end of the string - regardless of the
 420  modifiers used, and not before a newline.
 421  
 422  =item \G
 423  
 424  C<\G> is usually only used in combination with the C</g> modifier. If the
 425  C</g> modifier is used (and the match is done in scalar context), Perl will
 426  remember where in the source string the last match ended, and the next time,
 427  it will start the match from where it ended the previous time.
 428  
 429  C<\G> matches the point where the previous match ended, or the beginning
 430  of the string if there was no previous match.
 431  
 432  =for later add link to perlremodifiers
 433  
 434  Mnemonic: I<G>lobal.
 435  
 436  =item \b, \B
 437  
 438  C<\b> matches at any place between a word and a non-word character; C<\B>
 439  matches at any place between characters where C<\b> doesn't match. C<\b>
 440  and C<\B> assume there's a non-word character before the beginning and after
 441  the end of the source string; so C<\b> will match at the beginning (or end)
 442  of the source string if the source string begins (or ends) with a word
 443  character. Otherwise, C<\B> will match.
 444  
 445  Mnemonic: I<b>oundary.
 446  
 447  =back
 448  
 449  =head4 Examples
 450  
 451    "cat"   =~ /\Acat/;     # Match.
 452    "cat"   =~ /cat\Z/;     # Match.
 453    "cat\n" =~ /cat\Z/;     # Match.
 454    "cat\n" =~ /cat\z/;     # No match.
 455  
 456    "cat"   =~ /\bcat\b/;   # Matches.
 457    "cats"  =~ /\bcat\b/;   # No match.
 458    "cat"   =~ /\bcat\B/;   # No match.
 459    "cats"  =~ /\bcat\B/;   # Match.
 460  
 461    while ("cat dog" =~ /(\w+)/g) {
 462        print $1;           # Prints 'catdog'
 463    }
 464    while ("cat dog" =~ /\G(\w+)/g) {
 465        print $1;           # Prints 'cat'
 466    }
 467  
 468  =head2 Misc
 469  
 470  Here we document the backslash sequences that don't fall in one of the
 471  categories above. They are:
 472  
 473  =over 4
 474  
 475  =item \C
 476  
 477  C<\C> always matches a single octet, even if the source string is encoded
 478  in UTF-8 format, and the character to be matched is a multi-octet character.
 479  C<\C> was introduced in perl 5.6.
 480  
 481  Mnemonic: oI<C>tet.
 482  
 483  =item \K
 484  
 485  This is new in perl 5.10.0. Anything that is matched left of C<\K> is
 486  not included in C<$&> - and will not be replaced if the pattern is
 487  used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
 488  instead of C<s/(PAT1) PAT2/$1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 489  
 490  Mnemonic: I<K>eep.
 491  
 492  =item \R
 493  
 494  C<\R> matches a I<generic newline>, that is, anything that is considered
 495  a newline by Unicode. This includes all characters matched by C<\v>
 496  (vertical white space), and the multi character sequence C<"\x0D\x0A">
 497  (carriage return followed by a line feed, aka the network newline, or
 498  the newline used in Windows text files). C<\R> is equivalent with
 499  C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a more than one character,
 500  it cannot be put inside a bracketed character class; C</[\R]/> is an error.
 501  C<\R> was introduced in perl 5.10.0.
 502  
 503  Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 504  and more importantly because Unicode recommends such a regular expression
 505  metacharacter, and suggests C<\R> as the notation.
 506  
 507  =item \X
 508  
 509  This matches an extended Unicode I<combining character sequence>, and
 510  is equivalent to C<< (?>\PM\pM*) >>. C<\PM> matches any character that is
 511  not considered a Unicode mark character, while C<\pM> matches any character
 512  that is considered a Unicode mark character; so C<\X> matches any non
 513  mark character followed by zero or more mark characters. Mark characters
 514  include (but are not restricted to) I<combining characters> and
 515  I<vowel signs>.
 516  
 517  C<\X> matches quite well what normal (non-Unicode-programmer) usage
 518  would consider a single character: for example a base character
 519  (the C<\PM> above), for example a letter, followed by zero or more
 520  diacritics, which are I<combining characters> (the C<\pM*> above).
 521  
 522  Mnemonic: eI<X>tended Unicode character.
 523  
 524  =back
 525  
 526  =head4 Examples
 527  
 528   "\x{256}" =~ /^\C\C$/;    # Match as chr (256) takes 2 octets in UTF-8.
 529  
 530   $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'.
 531   $str =~ s/(.)\K\1//g;     # Delete duplicated characters.
 532  
 533   "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 534   "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 535   "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 536  
 537   "P\x{0307}" =~ /^\X$/     # \X matches a P with a dot above.
 538  
 539  =cut