[Summary view] [Print] [Text view]

   1  =head1 NAME
   2  
   3  perluniintro - Perl Unicode introduction
   4  
   5  =head1 DESCRIPTION
   6  
   7  This document gives a general idea of Unicode and how to use Unicode
   8  in Perl.
   9  
  10  =head2 Unicode
  11  
  12  Unicode is a character set standard which plans to codify all of the
  13  writing systems of the world, plus many other symbols.
  14  
  15  Unicode and ISO/IEC 10646 are coordinated standards that provide code
  16  points for characters in almost all modern character set standards,
  17  covering more than 30 writing systems and hundreds of languages,
  18  including all commercially-important modern languages.  All characters
  19  in the largest Chinese, Japanese, and Korean dictionaries are also
  20  encoded. The standards will eventually cover almost all characters in
  21  more than 250 writing systems and thousands of languages.
  22  Unicode 1.0 was released in October 1991, and 4.0 in April 2003.
  23  
  24  A Unicode I<character> is an abstract entity.  It is not bound to any
  25  particular integer width, especially not to the C language C<char>.
  26  Unicode is language-neutral and display-neutral: it does not encode the
  27  language of the text and it does not define fonts or other graphical
  28  layout details.  Unicode operates on characters and on text built from
  29  those characters.
  30  
  31  Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
  32  SMALL LETTER ALPHA> and unique numbers for the characters, in this
  33  case 0x0041 and 0x03B1, respectively.  These unique numbers are called
  34  I<code points>.
  35  
  36  The Unicode standard prefers using hexadecimal notation for the code
  37  points.  If numbers like C<0x0041> are unfamiliar to you, take a peek
  38  at a later section, L</"Hexadecimal Notation">.  The Unicode standard
  39  uses the notation C<U+0041 LATIN CAPITAL LETTER A>, to give the
  40  hexadecimal code point and the normative name of the character.
  41  
  42  Unicode also defines various I<properties> for the characters, like
  43  "uppercase" or "lowercase", "decimal digit", or "punctuation";
  44  these properties are independent of the names of the characters.
  45  Furthermore, various operations on the characters like uppercasing,
  46  lowercasing, and collating (sorting) are defined.
  47  
  48  A Unicode character consists either of a single code point, or a
  49  I<base character> (like C<LATIN CAPITAL LETTER A>), followed by one or
  50  more I<modifiers> (like C<COMBINING ACUTE ACCENT>).  This sequence of
  51  base character and modifiers is called a I<combining character
  52  sequence>.
  53  
  54  Whether to call these combining character sequences "characters"
  55  depends on your point of view. If you are a programmer, you probably
  56  would tend towards seeing each element in the sequences as one unit,
  57  or "character".  The whole sequence could be seen as one "character",
  58  however, from the user's point of view, since that's probably what it
  59  looks like in the context of the user's language.
  60  
  61  With this "whole sequence" view of characters, the total number of
  62  characters is open-ended. But in the programmer's "one unit is one
  63  character" point of view, the concept of "characters" is more
  64  deterministic.  In this document, we take that second  point of view:
  65  one "character" is one Unicode code point, be it a base character or
  66  a combining character.
  67  
  68  For some combinations, there are I<precomposed> characters.
  69  C<LATIN CAPITAL LETTER A WITH ACUTE>, for example, is defined as
  70  a single code point.  These precomposed characters are, however,
  71  only available for some combinations, and are mainly
  72  meant to support round-trip conversions between Unicode and legacy
  73  standards (like the ISO 8859).  In the general case, the composing
  74  method is more extensible.  To support conversion between
  75  different compositions of the characters, various I<normalization
  76  forms> to standardize representations are also defined.
  77  
  78  Because of backward compatibility with legacy encodings, the "a unique
  79  number for every character" idea breaks down a bit: instead, there is
  80  "at least one number for every character".  The same character could
  81  be represented differently in several legacy encodings.  The
  82  converse is also not true: some code points do not have an assigned
  83  character.  Firstly, there are unallocated code points within
  84  otherwise used blocks.  Secondly, there are special Unicode control
  85  characters that do not represent true characters.
  86  
  87  A common myth about Unicode is that it would be "16-bit", that is,
  88  Unicode is only represented as C<0x10000> (or 65536) characters from
  89  C<0x0000> to C<0xFFFF>.  B<This is untrue.>  Since Unicode 2.0 (July
  90  1996), Unicode has been defined all the way up to 21 bits (C<0x10FFFF>),
  91  and since Unicode 3.1 (March 2001), characters have been defined
  92  beyond C<0xFFFF>.  The first C<0x10000> characters are called the
  93  I<Plane 0>, or the I<Basic Multilingual Plane> (BMP).  With Unicode
  94  3.1, 17 (yes, seventeen) planes in all were defined--but they are
  95  nowhere near full of defined characters, yet.
  96  
  97  Another myth is that the 256-character blocks have something to
  98  do with languages--that each block would define the characters used
  99  by a language or a set of languages.  B<This is also untrue.>
 100  The division into blocks exists, but it is almost completely
 101  accidental--an artifact of how the characters have been and
 102  still are allocated.  Instead, there is a concept called I<scripts>,
 103  which is more useful: there is C<Latin> script, C<Greek> script, and
 104  so on.  Scripts usually span varied parts of several blocks.
 105  For further information see L<Unicode::UCD>.
 106  
 107  The Unicode code points are just abstract numbers.  To input and
 108  output these abstract numbers, the numbers must be I<encoded> or
 109  I<serialised> somehow.  Unicode defines several I<character encoding
 110  forms>, of which I<UTF-8> is perhaps the most popular.  UTF-8 is a
 111  variable length encoding that encodes Unicode characters as 1 to 6
 112  bytes (only 4 with the currently defined characters).  Other encodings
 113  include UTF-16 and UTF-32 and their big- and little-endian variants
 114  (UTF-8 is byte-order independent) The ISO/IEC 10646 defines the UCS-2
 115  and UCS-4 encoding forms.
 116  
 117  For more information about encodings--for instance, to learn what
 118  I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
 119  
 120  =head2 Perl's Unicode Support
 121  
 122  Starting from Perl 5.6.0, Perl has had the capacity to handle Unicode
 123  natively.  Perl 5.8.0, however, is the first recommended release for
 124  serious Unicode work.  The maintenance release 5.6.1 fixed many of the
 125  problems of the initial Unicode implementation, but for example
 126  regular expressions still do not work with Unicode in 5.6.1.
 127  
 128  B<Starting from Perl 5.8.0, the use of C<use utf8> is no longer
 129  necessary.> In earlier releases the C<utf8> pragma was used to declare
 130  that operations in the current block or file would be Unicode-aware.
 131  This model was found to be wrong, or at least clumsy: the "Unicodeness"
 132  is now carried with the data, instead of being attached to the
 133  operations.  Only one case remains where an explicit C<use utf8> is
 134  needed: if your Perl script itself is encoded in UTF-8, you can use
 135  UTF-8 in your identifier names, and in string and regular expression
 136  literals, by saying C<use utf8>.  This is not the default because
 137  scripts with legacy 8-bit data in them would break.  See L<utf8>.
 138  
 139  =head2 Perl's Unicode Model
 140  
 141  Perl supports both pre-5.6 strings of eight-bit native bytes, and
 142  strings of Unicode characters.  The principle is that Perl tries to
 143  keep its data as eight-bit bytes for as long as possible, but as soon
 144  as Unicodeness cannot be avoided, the data is transparently upgraded
 145  to Unicode.
 146  
 147  Internally, Perl currently uses either whatever the native eight-bit
 148  character set of the platform (for example Latin-1) is, defaulting to
 149  UTF-8, to encode Unicode strings. Specifically, if all code points in
 150  the string are C<0xFF> or less, Perl uses the native eight-bit
 151  character set.  Otherwise, it uses UTF-8.
 152  
 153  A user of Perl does not normally need to know nor care how Perl
 154  happens to encode its internal strings, but it becomes relevant when
 155  outputting Unicode strings to a stream without a PerlIO layer -- one with
 156  the "default" encoding.  In such a case, the raw bytes used internally
 157  (the native character set or UTF-8, as appropriate for each string)
 158  will be used, and a "Wide character" warning will be issued if those
 159  strings contain a character beyond 0x00FF.
 160  
 161  For example,
 162  
 163        perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
 164  
 165  produces a fairly useless mixture of native bytes and UTF-8, as well
 166  as a warning:
 167  
 168       Wide character in print at ...
 169  
 170  To output UTF-8, use the C<:encoding> or C<:utf8> output layer.  Prepending
 171  
 172        binmode(STDOUT, ":utf8");
 173  
 174  to this sample program ensures that the output is completely UTF-8,
 175  and removes the program's warning.
 176  
 177  You can enable automatic UTF-8-ification of your standard file
 178  handles, default C<open()> layer, and C<@ARGV> by using either
 179  the C<-C> command line switch or the C<PERL_UNICODE> environment
 180  variable, see L<perlrun> for the documentation of the C<-C> switch.
 181  
 182  Note that this means that Perl expects other software to work, too:
 183  if Perl has been led to believe that STDIN should be UTF-8, but then
 184  STDIN coming in from another command is not UTF-8, Perl will complain
 185  about the malformed UTF-8.
 186  
 187  All features that combine Unicode and I/O also require using the new
 188  PerlIO feature.  Almost all Perl 5.8 platforms do use PerlIO, though:
 189  you can see whether yours is by running "perl -V" and looking for
 190  C<useperlio=define>.
 191  
 192  =head2 Unicode and EBCDIC
 193  
 194  Perl 5.8.0 also supports Unicode on EBCDIC platforms.  There,
 195  Unicode support is somewhat more complex to implement since
 196  additional conversions are needed at every step.  Some problems
 197  remain, see L<perlebcdic> for details.
 198  
 199  In any case, the Unicode support on EBCDIC platforms is better than
 200  in the 5.6 series, which didn't work much at all for EBCDIC platform.
 201  On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
 202  instead of UTF-8.  The difference is that as UTF-8 is "ASCII-safe" in
 203  that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
 204  "EBCDIC-safe".
 205  
 206  =head2 Creating Unicode
 207  
 208  To create Unicode characters in literals for code points above C<0xFF>,
 209  use the C<\x{...}> notation in double-quoted strings:
 210  
 211      my $smiley = "\x{263a}";
 212  
 213  Similarly, it can be used in regular expression literals
 214  
 215      $smiley =~ /\x{263a}/;
 216  
 217  At run-time you can use C<chr()>:
 218  
 219      my $hebrew_alef = chr(0x05d0);
 220  
 221  See L</"Further Resources"> for how to find all these numeric codes.
 222  
 223  Naturally, C<ord()> will do the reverse: it turns a character into
 224  a code point.
 225  
 226  Note that C<\x..> (no C<{}> and only two hexadecimal digits), C<\x{...}>,
 227  and C<chr(...)> for arguments less than C<0x100> (decimal 256)
 228  generate an eight-bit character for backward compatibility with older
 229  Perls.  For arguments of C<0x100> or more, Unicode characters are
 230  always produced. If you want to force the production of Unicode
 231  characters regardless of the numeric value, use C<pack("U", ...)>
 232  instead of C<\x..>, C<\x{...}>, or C<chr()>.
 233  
 234  You can also use the C<charnames> pragma to invoke characters
 235  by name in double-quoted strings:
 236  
 237      use charnames ':full';
 238      my $arabic_alef = "\N{ARABIC LETTER ALEF}";
 239  
 240  And, as mentioned above, you can also C<pack()> numbers into Unicode
 241  characters:
 242  
 243     my $georgian_an  = pack("U", 0x10a0);
 244  
 245  Note that both C<\x{...}> and C<\N{...}> are compile-time string
 246  constants: you cannot use variables in them.  if you want similar
 247  run-time functionality, use C<chr()> and C<charnames::vianame()>.
 248  
 249  If you want to force the result to Unicode characters, use the special
 250  C<"U0"> prefix.  It consumes no arguments but causes the following bytes
 251  to be interpreted as the UTF-8 encoding of Unicode characters:
 252  
 253     my $chars = pack("U0W*", 0x80, 0x42);
 254  
 255  Likewise, you can stop such UTF-8 interpretation by using the special
 256  C<"C0"> prefix.
 257  
 258  =head2 Handling Unicode
 259  
 260  Handling Unicode is for the most part transparent: just use the
 261  strings as usual.  Functions like C<index()>, C<length()>, and
 262  C<substr()> will work on the Unicode characters; regular expressions
 263  will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
 264  
 265  Note that Perl considers combining character sequences to be
 266  separate characters, so for example
 267  
 268      use charnames ':full';
 269      print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"), "\n";
 270  
 271  will print 2, not 1.  The only exception is that regular expressions
 272  have C<\X> for matching a combining character sequence.
 273  
 274  Life is not quite so transparent, however, when working with legacy
 275  encodings, I/O, and certain special cases:
 276  
 277  =head2 Legacy Encodings
 278  
 279  When you combine legacy data and Unicode the legacy data needs
 280  to be upgraded to Unicode.  Normally ISO 8859-1 (or EBCDIC, if
 281  applicable) is assumed.
 282  
 283  The C<Encode> module knows about many encodings and has interfaces
 284  for doing conversions between those encodings:
 285  
 286      use Encode 'decode';
 287      $data = decode("iso-8859-3", $data); # convert from legacy to utf-8
 288  
 289  =head2 Unicode I/O
 290  
 291  Normally, writing out Unicode data
 292  
 293      print FH $some_string_with_unicode, "\n";
 294  
 295  produces raw bytes that Perl happens to use to internally encode the
 296  Unicode string.  Perl's internal encoding depends on the system as
 297  well as what characters happen to be in the string at the time. If
 298  any of the characters are at code points C<0x100> or above, you will get
 299  a warning.  To ensure that the output is explicitly rendered in the
 300  encoding you desire--and to avoid the warning--open the stream with
 301  the desired encoding. Some examples:
 302  
 303      open FH, ">:utf8", "file";
 304  
 305      open FH, ">:encoding(ucs2)",      "file";
 306      open FH, ">:encoding(UTF-8)",     "file";
 307      open FH, ">:encoding(shift_jis)", "file";
 308  
 309  and on already open streams, use C<binmode()>:
 310  
 311      binmode(STDOUT, ":utf8");
 312  
 313      binmode(STDOUT, ":encoding(ucs2)");
 314      binmode(STDOUT, ":encoding(UTF-8)");
 315      binmode(STDOUT, ":encoding(shift_jis)");
 316  
 317  The matching of encoding names is loose: case does not matter, and
 318  many encodings have several aliases.  Note that the C<:utf8> layer
 319  must always be specified exactly like that; it is I<not> subject to
 320  the loose matching of encoding names. Also note that C<:utf8> is unsafe for
 321  input, because it accepts the data without validating that it is indeed valid
 322  UTF8.
 323  
 324  See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
 325  L<Encode::PerlIO> for the C<:encoding()> layer, and
 326  L<Encode::Supported> for many encodings supported by the C<Encode>
 327  module.
 328  
 329  Reading in a file that you know happens to be encoded in one of the
 330  Unicode or legacy encodings does not magically turn the data into
 331  Unicode in Perl's eyes.  To do that, specify the appropriate
 332  layer when opening files
 333  
 334      open(my $fh,'<:encoding(utf8)', 'anything');
 335      my $line_of_unicode = <$fh>;
 336  
 337      open(my $fh,'<:encoding(Big5)', 'anything');
 338      my $line_of_unicode = <$fh>;
 339  
 340  The I/O layers can also be specified more flexibly with
 341  the C<open> pragma.  See L<open>, or look at the following example.
 342  
 343      use open ':encoding(utf8)'; # input/output default encoding will be UTF-8
 344      open X, ">file";
 345      print X chr(0x100), "\n";
 346      close X;
 347      open Y, "<file";
 348      printf "%#x\n", ord(<Y>); # this should print 0x100
 349      close Y;
 350  
 351  With the C<open> pragma you can use the C<:locale> layer
 352  
 353      BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
 354      # the :locale will probe the locale environment variables like LC_ALL
 355      use open OUT => ':locale'; # russki parusski
 356      open(O, ">koi8");
 357      print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
 358      close O;
 359      open(I, "<koi8");
 360      printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
 361      close I;
 362  
 363  These methods install a transparent filter on the I/O stream that
 364  converts data from the specified encoding when it is read in from the
 365  stream.  The result is always Unicode.
 366  
 367  The L<open> pragma affects all the C<open()> calls after the pragma by
 368  setting default layers.  If you want to affect only certain
 369  streams, use explicit layers directly in the C<open()> call.
 370  
 371  You can switch encodings on an already opened stream by using
 372  C<binmode()>; see L<perlfunc/binmode>.
 373  
 374  The C<:locale> does not currently (as of Perl 5.8.0) work with
 375  C<open()> and C<binmode()>, only with the C<open> pragma.  The
 376  C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
 377  C<binmode()>, and the C<open> pragma.
 378  
 379  Similarly, you may use these I/O layers on output streams to
 380  automatically convert Unicode to the specified encoding when it is
 381  written to the stream. For example, the following snippet copies the
 382  contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
 383  the file "text.utf8", encoded as UTF-8:
 384  
 385      open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
 386      open(my $unicode, '>:utf8',                  'text.utf8');
 387      while (<$nihongo>) { print $unicode $_ }
 388  
 389  The naming of encodings, both by the C<open()> and by the C<open>
 390  pragma allows for flexible names: C<koi8-r> and C<KOI8R> will both be
 391  understood.
 392  
 393  Common encodings recognized by ISO, MIME, IANA, and various other
 394  standardisation organisations are recognised; for a more detailed
 395  list see L<Encode::Supported>.
 396  
 397  C<read()> reads characters and returns the number of characters.
 398  C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
 399  and C<sysseek()>.
 400  
 401  Notice that because of the default behaviour of not doing any
 402  conversion upon input if there is no default layer,
 403  it is easy to mistakenly write code that keeps on expanding a file
 404  by repeatedly encoding the data:
 405  
 406      # BAD CODE WARNING
 407      open F, "file";
 408      local $/; ## read in the whole file of 8-bit characters
 409      $t = <F>;
 410      close F;
 411      open F, ">:encoding(utf8)", "file";
 412      print F $t; ## convert to UTF-8 on output
 413      close F;
 414  
 415  If you run this code twice, the contents of the F<file> will be twice
 416  UTF-8 encoded.  A C<use open ':encoding(utf8)'> would have avoided the
 417  bug, or explicitly opening also the F<file> for input as UTF-8.
 418  
 419  B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
 420  Perl has been built with the new PerlIO feature (which is the default
 421  on most systems).
 422  
 423  =head2 Displaying Unicode As Text
 424  
 425  Sometimes you might want to display Perl scalars containing Unicode as
 426  simple ASCII (or EBCDIC) text.  The following subroutine converts
 427  its argument so that Unicode characters with code points greater than
 428  255 are displayed as C<\x{...}>, control characters (like C<\n>) are
 429  displayed as C<\x..>, and the rest of the characters as themselves:
 430  
 431     sub nice_string {
 432         join("",
 433           map { $_ > 255 ?                  # if wide character...
 434                 sprintf("\\x{%04X}", $_) :  # \x{...}
 435                 chr($_) =~ /[[:cntrl:]]/ ?  # else if control character ...
 436                 sprintf("\\x%02X", $_) :    # \x..
 437                 quotemeta(chr($_))          # else quoted or as themselves
 438           } unpack("W*", $_[0]));           # unpack Unicode characters
 439     }
 440  
 441  For example,
 442  
 443     nice_string("foo\x{100}bar\n")
 444  
 445  returns the string
 446  
 447     'foo\x{0100}bar\x0A'
 448  
 449  which is ready to be printed.
 450  
 451  =head2 Special Cases
 452  
 453  =over 4
 454  
 455  =item *
 456  
 457  Bit Complement Operator ~ And vec()
 458  
 459  The bit complement operator C<~> may produce surprising results if
 460  used on strings containing characters with ordinal values above
 461  255. In such a case, the results are consistent with the internal
 462  encoding of the characters, but not with much else. So don't do
 463  that. Similarly for C<vec()>: you will be operating on the
 464  internally-encoded bit patterns of the Unicode characters, not on
 465  the code point values, which is very probably not what you want.
 466  
 467  =item *
 468  
 469  Peeking At Perl's Internal Encoding
 470  
 471  Normal users of Perl should never care how Perl encodes any particular
 472  Unicode string (because the normal ways to get at the contents of a
 473  string with Unicode--via input and output--should always be via
 474  explicitly-defined I/O layers). But if you must, there are two
 475  ways of looking behind the scenes.
 476  
 477  One way of peeking inside the internal encoding of Unicode characters
 478  is to use C<unpack("C*", ...> to get the bytes of whatever the string
 479  encoding happens to be, or C<unpack("U0..", ...)> to get the bytes of the
 480  UTF-8 encoding:
 481  
 482      # this prints  c4 80  for the UTF-8 bytes 0xc4 0x80
 483      print join(" ", unpack("U0(H2)*", pack("U", 0x100))), "\n";
 484  
 485  Yet another way would be to use the Devel::Peek module:
 486  
 487      perl -MDevel::Peek -e 'Dump(chr(0x100))'
 488  
 489  That shows the C<UTF8> flag in FLAGS and both the UTF-8 bytes
 490  and Unicode characters in C<PV>.  See also later in this document
 491  the discussion about the C<utf8::is_utf8()> function.
 492  
 493  =back
 494  
 495  =head2 Advanced Topics
 496  
 497  =over 4
 498  
 499  =item *
 500  
 501  String Equivalence
 502  
 503  The question of string equivalence turns somewhat complicated
 504  in Unicode: what do you mean by "equal"?
 505  
 506  (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
 507  C<LATIN CAPITAL LETTER A>?)
 508  
 509  The short answer is that by default Perl compares equivalence (C<eq>,
 510  C<ne>) based only on code points of the characters.  In the above
 511  case, the answer is no (because 0x00C1 != 0x0041).  But sometimes, any
 512  CAPITAL LETTER As should be considered equal, or even As of any case.
 513  
 514  The long answer is that you need to consider character normalization
 515  and casing issues: see L<Unicode::Normalize>, Unicode Technical
 516  Reports #15 and #21, I<Unicode Normalization Forms> and I<Case
 517  Mappings>, http://www.unicode.org/unicode/reports/tr15/ and
 518  http://www.unicode.org/unicode/reports/tr21/
 519  
 520  As of Perl 5.8.0, the "Full" case-folding of I<Case
 521  Mappings/SpecialCasing> is implemented.
 522  
 523  =item *
 524  
 525  String Collation
 526  
 527  People like to see their strings nicely sorted--or as Unicode
 528  parlance goes, collated.  But again, what do you mean by collate?
 529  
 530  (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
 531  C<LATIN CAPITAL LETTER A WITH GRAVE>?)
 532  
 533  The short answer is that by default, Perl compares strings (C<lt>,
 534  C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
 535  characters.  In the above case, the answer is "after", since
 536  C<0x00C1> > C<0x00C0>.
 537  
 538  The long answer is that "it depends", and a good answer cannot be
 539  given without knowing (at the very least) the language context.
 540  See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
 541  http://www.unicode.org/unicode/reports/tr10/
 542  
 543  =back
 544  
 545  =head2 Miscellaneous
 546  
 547  =over 4
 548  
 549  =item *
 550  
 551  Character Ranges and Classes
 552  
 553  Character ranges in regular expression character classes (C</[a-z]/>)
 554  and in the C<tr///> (also known as C<y///>) operator are not magically
 555  Unicode-aware.  What this means that C<[A-Za-z]> will not magically start
 556  to mean "all alphabetic letters"; not that it does mean that even for
 557  8-bit characters, you should be using C</[[:alpha:]]/> in that case.
 558  
 559  For specifying character classes like that in regular expressions,
 560  you can use the various Unicode properties--C<\pL>, or perhaps
 561  C<\p{Alphabetic}>, in this particular case.  You can use Unicode
 562  code points as the end points of character ranges, but there is no
 563  magic associated with specifying a certain range.  For further
 564  information--there are dozens of Unicode character classes--see
 565  L<perlunicode>.
 566  
 567  =item *
 568  
 569  String-To-Number Conversions
 570  
 571  Unicode does define several other decimal--and numeric--characters
 572  besides the familiar 0 to 9, such as the Arabic and Indic digits.
 573  Perl does not support string-to-number conversion for digits other
 574  than ASCII 0 to 9 (and ASCII a to f for hexadecimal).
 575  
 576  =back
 577  
 578  =head2 Questions With Answers
 579  
 580  =over 4
 581  
 582  =item *
 583  
 584  Will My Old Scripts Break?
 585  
 586  Very probably not.  Unless you are generating Unicode characters
 587  somehow, old behaviour should be preserved.  About the only behaviour
 588  that has changed and which could start generating Unicode is the old
 589  behaviour of C<chr()> where supplying an argument more than 255
 590  produced a character modulo 255.  C<chr(300)>, for example, was equal
 591  to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
 592  BREVE.
 593  
 594  =item *
 595  
 596  How Do I Make My Scripts Work With Unicode?
 597  
 598  Very little work should be needed since nothing changes until you
 599  generate Unicode data.  The most important thing is getting input as
 600  Unicode; for that, see the earlier I/O discussion.
 601  
 602  =item *
 603  
 604  How Do I Know Whether My String Is In Unicode?
 605  
 606  You shouldn't care.  No, you really shouldn't.  No, really.  If you
 607  have to care--beyond the cases described above--it means that we
 608  didn't get the transparency of Unicode quite right.
 609  
 610  Okay, if you insist:
 611  
 612      print utf8::is_utf8($string) ? 1 : 0, "\n";
 613  
 614  But note that this doesn't mean that any of the characters in the
 615  string are necessary UTF-8 encoded, or that any of the characters have
 616  code points greater than 0xFF (255) or even 0x80 (128), or that the
 617  string has any characters at all.  All the C<is_utf8()> does is to
 618  return the value of the internal "utf8ness" flag attached to the
 619  C<$string>.  If the flag is off, the bytes in the scalar are interpreted
 620  as a single byte encoding.  If the flag is on, the bytes in the scalar
 621  are interpreted as the (multi-byte, variable-length) UTF-8 encoded code
 622  points of the characters.  Bytes added to an UTF-8 encoded string are
 623  automatically upgraded to UTF-8.  If mixed non-UTF-8 and UTF-8 scalars
 624  are merged (double-quoted interpolation, explicit concatenation, and
 625  printf/sprintf parameter substitution), the result will be UTF-8 encoded
 626  as if copies of the byte strings were upgraded to UTF-8: for example,
 627  
 628      $a = "ab\x80c";
 629      $b = "\x{100}";
 630      print "$a = $b\n";
 631  
 632  the output string will be UTF-8-encoded C<ab\x80c = \x{100}\n>, but
 633  C<$a> will stay byte-encoded.
 634  
 635  Sometimes you might really need to know the byte length of a string
 636  instead of the character length. For that use either the
 637  C<Encode::encode_utf8()> function or the C<bytes> pragma and its only
 638  defined function C<length()>:
 639  
 640      my $unicode = chr(0x100);
 641      print length($unicode), "\n"; # will print 1
 642      require Encode;
 643      print length(Encode::encode_utf8($unicode)), "\n"; # will print 2
 644      use bytes;
 645      print length($unicode), "\n"; # will also print 2
 646                                    # (the 0xC4 0x80 of the UTF-8)
 647  
 648  =item *
 649  
 650  How Do I Detect Data That's Not Valid In a Particular Encoding?
 651  
 652  Use the C<Encode> package to try converting it.
 653  For example,
 654  
 655      use Encode 'decode_utf8';
 656      eval { decode_utf8($string, Encode::FB_CROAK) };
 657      if ($@) {
 658          # $string is valid utf8
 659      } else {
 660          # $string is not valid utf8
 661      }
 662  
 663  Or use C<unpack> to try decoding it:
 664  
 665      use warnings;
 666      @chars = unpack("C0U*", $string_of_bytes_that_I_think_is_utf8);
 667  
 668  If invalid, a C<Malformed UTF-8 character> warning is produced. The "C0" means
 669  "process the string character per character".  Without that, the
 670  C<unpack("U*", ...)> would work in C<U0> mode (the default if the format
 671  string starts with C<U>) and it would return the bytes making up the UTF-8
 672  encoding of the target string, something that will always work.
 673  
 674  =item *
 675  
 676  How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
 677  
 678  This probably isn't as useful as you might think.
 679  Normally, you shouldn't need to.
 680  
 681  In one sense, what you are asking doesn't make much sense: encodings
 682  are for characters, and binary data are not "characters", so converting
 683  "data" into some encoding isn't meaningful unless you know in what
 684  character set and encoding the binary data is in, in which case it's
 685  not just binary data, now is it?
 686  
 687  If you have a raw sequence of bytes that you know should be
 688  interpreted via a particular encoding, you can use C<Encode>:
 689  
 690      use Encode 'from_to';
 691      from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
 692  
 693  The call to C<from_to()> changes the bytes in C<$data>, but nothing
 694  material about the nature of the string has changed as far as Perl is
 695  concerned.  Both before and after the call, the string C<$data>
 696  contains just a bunch of 8-bit bytes. As far as Perl is concerned,
 697  the encoding of the string remains as "system-native 8-bit bytes".
 698  
 699  You might relate this to a fictional 'Translate' module:
 700  
 701     use Translate;
 702     my $phrase = "Yes";
 703     Translate::from_to($phrase, 'english', 'deutsch');
 704     ## phrase now contains "Ja"
 705  
 706  The contents of the string changes, but not the nature of the string.
 707  Perl doesn't know any more after the call than before that the
 708  contents of the string indicates the affirmative.
 709  
 710  Back to converting data.  If you have (or want) data in your system's
 711  native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
 712  pack/unpack to convert to/from Unicode.
 713  
 714      $native_string  = pack("W*", unpack("U*", $Unicode_string));
 715      $Unicode_string = pack("U*", unpack("W*", $native_string));
 716  
 717  If you have a sequence of bytes you B<know> is valid UTF-8,
 718  but Perl doesn't know it yet, you can make Perl a believer, too:
 719  
 720      use Encode 'decode_utf8';
 721      $Unicode = decode_utf8($bytes);
 722  
 723  or:
 724  
 725      $Unicode = pack("U0a*", $bytes);
 726  
 727  You can convert well-formed UTF-8 to a sequence of bytes, but if
 728  you just want to convert random binary data into UTF-8, you can't.
 729  B<Any random collection of bytes isn't well-formed UTF-8>.  You can
 730  use C<unpack("C*", $string)> for the former, and you can create
 731  well-formed Unicode data by C<pack("U*", 0xff, ...)>.
 732  
 733  =item *
 734  
 735  How Do I Display Unicode?  How Do I Input Unicode?
 736  
 737  See http://www.alanwood.net/unicode/ and
 738  http://www.cl.cam.ac.uk/~mgk25/unicode.html
 739  
 740  =item *
 741  
 742  How Does Unicode Work With Traditional Locales?
 743  
 744  In Perl, not very well.  Avoid using locales through the C<locale>
 745  pragma.  Use only one or the other.  But see L<perlrun> for the
 746  description of the C<-C> switch and its environment counterpart,
 747  C<$ENV{PERL_UNICODE}> to see how to enable various Unicode features,
 748  for example by using locale settings.
 749  
 750  =back
 751  
 752  =head2 Hexadecimal Notation
 753  
 754  The Unicode standard prefers using hexadecimal notation because
 755  that more clearly shows the division of Unicode into blocks of 256 characters.
 756  Hexadecimal is also simply shorter than decimal.  You can use decimal
 757  notation, too, but learning to use hexadecimal just makes life easier
 758  with the Unicode standard.  The C<U+HHHH> notation uses hexadecimal,
 759  for example.
 760  
 761  The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
 762  a-f (or A-F, case doesn't matter).  Each hexadecimal digit represents
 763  four bits, or half a byte.  C<print 0x..., "\n"> will show a
 764  hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
 765  show a decimal number in hexadecimal.  If you have just the
 766  "hex digits" of a hexadecimal number, you can use the C<hex()> function.
 767  
 768      print 0x0009, "\n";    # 9
 769      print 0x000a, "\n";    # 10
 770      print 0x000f, "\n";    # 15
 771      print 0x0010, "\n";    # 16
 772      print 0x0011, "\n";    # 17
 773      print 0x0100, "\n";    # 256
 774  
 775      print 0x0041, "\n";    # 65
 776  
 777      printf "%x\n",  65;    # 41
 778      printf "%#x\n", 65;    # 0x41
 779  
 780      print hex("41"), "\n"; # 65
 781  
 782  =head2 Further Resources
 783  
 784  =over 4
 785  
 786  =item *
 787  
 788  Unicode Consortium
 789  
 790  http://www.unicode.org/
 791  
 792  =item *
 793  
 794  Unicode FAQ
 795  
 796  http://www.unicode.org/unicode/faq/
 797  
 798  =item *
 799  
 800  Unicode Glossary
 801  
 802  http://www.unicode.org/glossary/
 803  
 804  =item *
 805  
 806  Unicode Useful Resources
 807  
 808  http://www.unicode.org/unicode/onlinedat/resources.html
 809  
 810  =item *
 811  
 812  Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
 813  
 814  http://www.alanwood.net/unicode/
 815  
 816  =item *
 817  
 818  UTF-8 and Unicode FAQ for Unix/Linux
 819  
 820  http://www.cl.cam.ac.uk/~mgk25/unicode.html
 821  
 822  =item *
 823  
 824  Legacy Character Sets
 825  
 826  http://www.czyborra.com/
 827  http://www.eki.ee/letter/
 828  
 829  =item *
 830  
 831  The Unicode support files live within the Perl installation in the
 832  directory
 833  
 834      $Config{installprivlib}/unicore
 835  
 836  in Perl 5.8.0 or newer, and
 837  
 838      $Config{installprivlib}/unicode
 839  
 840  in the Perl 5.6 series.  (The renaming to F<lib/unicore> was done to
 841  avoid naming conflicts with lib/Unicode in case-insensitive filesystems.)
 842  The main Unicode data file is F<UnicodeData.txt> (or F<Unicode.301> in
 843  Perl 5.6.1.)  You can find the C<$Config{installprivlib}> by
 844  
 845      perl "-V:installprivlib"
 846  
 847  You can explore various information from the Unicode data files using
 848  the C<Unicode::UCD> module.
 849  
 850  =back
 851  
 852  =head1 UNICODE IN OLDER PERLS
 853  
 854  If you cannot upgrade your Perl to 5.8.0 or later, you can still
 855  do some Unicode processing by using the modules C<Unicode::String>,
 856  C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
 857  If you have the GNU recode installed, you can also use the
 858  Perl front-end C<Convert::Recode> for character conversions.
 859  
 860  The following are fast conversions from ISO 8859-1 (Latin-1) bytes
 861  to UTF-8 bytes and back, the code works even with older Perl 5 versions.
 862  
 863      # ISO 8859-1 to UTF-8
 864      s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
 865  
 866      # UTF-8 to ISO 8859-1
 867      s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
 868  
 869  =head1 SEE ALSO
 870  
 871  L<perlunitut>, L<perlunicode>, L<Encode>, L<open>, L<utf8>, L<bytes>,
 872  L<perlretut>, L<perlrun>, L<Unicode::Collate>, L<Unicode::Normalize>,
 873  L<Unicode::UCD>
 874  
 875  =head1 ACKNOWLEDGMENTS
 876  
 877  Thanks to the kind readers of the perl5-porters@perl.org,
 878  perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
 879  mailing lists for their valuable feedback.
 880  
 881  =head1 AUTHOR, COPYRIGHT, AND LICENSE
 882  
 883  Copyright 2001-2002 Jarkko Hietaniemi E<lt>jhi@iki.fiE<gt>
 884  
 885  This document may be distributed under the same terms as Perl itself.